Delirio

(es) Delirio

(eo) Deliro

http://dx.doi.org/10.13140/RG.2.2.34092.90243

Descripción artística:

Una espiral formada por la cinta enrrollada de una Máquina de Turing binaria. En el centro de la imagen está el motor de la máquina.

Motivación:

Los recuerdos del curso de Teoría Matemática de la Computación.

Descripción técnica:

Dos espirales exponenciales entrelazadas con ecuaciones $r=\pm {\left(\frac{11}{10}\right)}^{\theta }$, con $0\le \theta \le 20\pi$. Cada celda contiene un bit y tiene igual probabilidad de ser uno o cero.

Archivos

Código (CFDG):

# Copyright 2015 Eduardo Adam Navas López
# Este archivo es Software Libre liberado bajo la licencia GNU GPLv3 o su versión más reciente:
# http://www.gnu.org/licenses/gpl.html

#Para generar la imagen:
#$ cfdg -s 8000 -o turing.png turing.cfdg

pi = 3.14159

NUMBITS = 750 #Número de bits para formar la curva
PROP_TAM_BIT = 16
ANG_INI = 0
ANG_FIN = 20*pi #10*pi

startshape principal

shape principal{
 #Unión de las espirales
 SQUARE[s 2 (1/PROP_TAM_BIT)]
 
 #Espirales
 loop i = NUMBITS []{
  angulo = ANG_INI + i*(ANG_FIN - ANG_INI)/(NUMBITS-1)
  radio = 1.1^angulo
  angulo_grad = angulo * 180 / pi
  x_b = radio * cos(angulo_grad)
  y_b = radio * sin(angulo_grad)
  cuadro[r (angulo_grad+84.5) x (x_b)  y (y_b)  s (radio/PROP_TAM_BIT)]
  cuadro[r (angulo_grad+84.5) x (-x_b) y (-y_b) s (radio/PROP_TAM_BIT)]
 }
 
 #Prolongación de las espirales
 angulo = ANG_INI + NUMBITS*(ANG_FIN - ANG_INI)/(NUMBITS-1)
 radio = 1.1^angulo
 angulo_grad = angulo * 180 / pi
 x_b = radio * cos(angulo_grad)
 y_b = radio * sin(angulo_grad)
 cuadroAbierto[r (angulo_grad+84.5) x (x_b)  y (y_b)  s (radio/PROP_TAM_BIT)]
 cuadroAbierto[r (angulo_grad+84.5) x (-x_b) y (-y_b) s (radio/PROP_TAM_BIT)]
}


shape cuadro{
 SQUARE[s 1.45 h 206 sat 81 b 0.72]
 SQUARE[b 1]
 bit[s 0.7]
}

shape bit
rule {
 SQUARE[s 0.1 1  h 2   sat 81 b 0.72]
}
rule {
 CIRCLE[s 0.9 1  h 2   sat 81 b 0.72]
 CIRCLE[s 0.7 0.9 b 1]
}

shape cuadroAbierto{
 SQUARE[s 1.45 0.20 y 0.62     h 206 sat 81 b 0.72]
 SQUARE[s 1.45 0.20 y (-0.62)  h 206 sat 81 b 0.72]
}