# Copyright 2015 Eduardo Adam Navas López
# Este archivo es Software Libre liberado bajo la licencia GNU GPLv3 o su versión más reciente:
# http://www.gnu.org/licenses/gpl.html
#Para generar la imagen:
#$ cfdg -b 0 -s 8000 rgb.cfdg rgb.png
#Número de hexágonos de radio
RADIO = 64 #16
startshape cubo
PORCENTAJE_ESPACIO = 1.1
const1_r3 = (1/sqrt(3))
MEDIOANCHO = (sqrt(3)/2)*PORCENTAJE_ESPACIO
MEDIOALTO = 0.5*PORCENTAJE_ESPACIO
SATMIN = 0.01
shape prueba{
hexagono1[]
hexagono2[]
hexagono3[]
}
shape cubo {
loop bloque = 3 [r 120]{
loop anillo = RADIO []{
loop i = (anillo+1) []{
loop j = (anillo+1) []{
px = (i*MEDIOANCHO-j*MEDIOANCHO)
py = (MEDIOALTO*(i+j))
hexagono1[x px y py b 1
sat ((1-SATMIN)*max(i,j)/(RADIO-1)+SATMIN)
h (atan2(py,px)-30+bloque*120) ]
}
}
}
}
}
shape dosTriangulos {
loop i = 2 [r 60]{
TRIANGLE[y const1_r3 r 180]
}
}
shape hexagono1 {
dosTriangulos[r -30]
}
shape hexagono2 {
dosTriangulos[r 90]
}
shape hexagono3 {
dosTriangulos[r 210]
}
# Copyright 2015 Eduardo Adam Navas López
# Este archivo es Software Libre liberado bajo la licencia GNU GPLv3 o su versión más reciente:
# http://www.gnu.org/licenses/gpl.html
#Para generar la imagen:
#$ cfdg -b 0 -s 1000 ragnarok.cfdg ragnarok.png
#Posibilidades de ragnarok
#-1.384286,0.004286
#-1.3, 0.00525
#-1.3,0.0
#-1.5, 0.0
startshape rag(-1.4, 0.0)
LIMITE = 1000 #Resolución de la imagen
MAXPASOS = 100
LIMIZQ = -0.6
LIMDER = 0.6
LIMARRIBA = 0.6
LIMABAJO = -0.6
TAMX = (LIMDER-LIMIZQ)/(LIMITE-1)
TAMY = (LIMARRIBA-LIMABAJO)/(LIMITE-1)
pasos(numPasos,z_r,z_i,c_r,c_i) =
if((numPasos < MAXPASOS) && (z_r*z_r+z_i*z_i<4),
pasos(numPasos+1, z_r*z_r - z_i*z_i + c_r, 2*z_r*z_i + c_i, c_r, c_i),
numPasos)
shape rag(c_r,c_i) {
loop i = LIMITE/2 [] {
z_i = (LIMARRIBA-LIMABAJO)*i/(LIMITE-1) + LIMABAJO #y
loop j = LIMITE/2 [] {
z_r = (LIMDER-LIMIZQ)*j/(LIMITE-1) + LIMIZQ #x
numPasos = pasos(0, z_r, z_i, c_r, c_i)
brillo = (1+(1-numPasos)/(MAXPASOS-1))
SQUARE[x z_r y z_i size TAMX TAMY b brillo]
SQUARE[x (-z_r) y z_i size TAMX TAMY b brillo]
SQUARE[x z_r y (-z_i) size TAMX TAMY b brillo]
SQUARE[x (-z_r) y (-z_i) size TAMX TAMY b brillo]
}
}
}
# Copyright 2015 Eduardo Adam Navas López
# Este archivo es Software Libre liberado bajo la licencia GNU GPLv3 o su versión más reciente:
# http://www.gnu.org/licenses/gpl.html
#Para generar la imagen:
#$ cfdg -b 0 -s 8000 hsb.cfdg hsb.png
startshape cuadros
#Va aumentando la saturación con un brillo constante (máximo=1) y luego va disminuyendo el brillo con una saturación constante (máximo=1), de manera consecutiva
shape cuadros{
numCols = 20 #Número de las filas/columnas
ang = 90 #Ángulo de giro en cada fila/columna
minSat = 0.2 #Límite inferior de la saturación [0,1)
minBrillo = 0.2 #Límite inferior del brillo [0,1)
d = sqrt(2)
loop j=(numCols/2) [y (-d)]{
loop i=(numCols) [x d] {
SQUARE[b 1
r (i*ang/(numCols-1)+j*ang/(numCols-1))
h (i*359/numCols)
sat (minSat+j*(1-minSat)/(numCols/2-1))]
}
}
loop j=(numCols/2) [y (-d)]{
loop i=(numCols) [x d] {
SQUARE[sat 1
r (i*ang/(numCols-1)+j*ang/(numCols-1)+45)
h (i*359/numCols)
b (1+j*(minBrillo-1)/(numCols/2-1)) y -(d*numCols/2)]
}
}
}
# Copyright 2015 Eduardo Adam Navas López
# Este archivo es Software Libre liberado bajo la licencia GNU GPLv3 o su versión más reciente:
# http://www.gnu.org/licenses/gpl.html
#Para generar la imagen:
#$ cfdg -s 8000 girasol.cfdg girasol.png
CF::Size = [s 183 183]
startshape espiral
NUMSEGMENTOS = 2000 #Número de segmentos para formar la curva
TAM = 2
phi = (1+sqrt(5))/2
pi = 3.14159
shape espiral {
loop i = NUMSEGMENTOS [] {
ang = 2*pi*(i+1)/(phi*phi) #+1 para evitar el punto rojo del centro
rad = TAM*sqrt(i+1)
ang_grad = 180*ang/pi
xc = rad * cos(ang_grad)
yc = rad * sin(ang_grad)
CIRCLE[x xc y yc hue (ang_grad) b 1 sat 1 s 3]
}
loop j = (NUMSEGMENTOS*10/9) []{ # Si sólo son NUMSEGMENTOS quedan huecos en las esquinas
i = j+NUMSEGMENTOS
ang = 2*pi*(i)/(phi*phi)
rad = TAM*sqrt(i)
ang_grad = 180*ang/pi
xc = rad * cos(ang_grad)
yc = rad * sin(ang_grad)
CIRCLE[x xc y yc hue (ang_grad) b 1 sat 0.3 s 3 ]
}
}
# Copyright 2015 Eduardo Adam Navas López
# Este archivo es Software Libre liberado bajo la licencia GNU GPLv3 o su versión más reciente:
# http://www.gnu.org/licenses/gpl.html
#Para generar la imagen:
#$ cfdg -s 8000 -v FLVQXF gauss.cfdg gauss.png
NUMSEG = 50 #Número de segmentos para formar la curva
LIMITE = 2.5 #Intervalo de dibujo: [-lim,lim]
NUMCURVAS = 750 #Número de campanas a dibujar
LIM_AMPLITUD = 4
LIM_Y = 5
LIM_X = 5
LIM_SUP_DESV = 2
LIM_INF_DESV = 0.5
MAX_BRILLO = 1.0
CF::Size = [s (2*LIM_X) (2*LIM_X) x 0 y -(LIM_Y*0.2)]
startshape principal
path campana(media, desviacion, amplitud) {
MOVETO(media, amplitud) #mitad derecha
loop i = NUMSEG [] {
xc = ((LIMITE*(i+1)/(NUMSEG-1)) +media)
LINETO(xc, amplitud*exp(-((xc-media)/desviacion)^2))
}
STROKE(CF::RoundCap)[]
MOVETO(media, amplitud) #mitad izquierda
loop i = NUMSEG [] {
xc = ((-LIMITE*(i+1)/(NUMSEG-1)) +media)
LINETO(xc, amplitud*exp(-((xc-media)/desviacion)^2))
}
STROKE(CF::RoundCap)[]
}
shape principal{
FILL[]
loop i = NUMCURVAS []{
campana(rand(-LIM_X, LIM_X), rand(LIM_INF_DESV,LIM_SUP_DESV), rand(LIM_AMPLITUD*0.1,LIM_AMPLITUD)) [y rand(-LIM_Y,LIM_Y)
hue randint(360)
b (i*MAX_BRILLO/(NUMCURVAS-1))
sat 1]
}
campana(0,1,1)[b 1 sat 0 s 2] #curva blanca en el centro
}
# Copyright 2015 Eduardo Adam Navas López
# Este archivo es Software Libre liberado bajo la licencia GNU GPLv3 o su versión más reciente:
# http://www.gnu.org/licenses/gpl.html
#Para generar la imagen:
#$ cfdg -b 0 -s 1000 fiordos.cfdg fiordos.png
startshape fiordos(-1.384286,0.004286)
LIMITE = 1000 #Resolución de la imagen
MAXPASOS = 300
LIMIZQ = 0.01
LIMDER = 0.09
LIMARRIBA = 0.10
LIMABAJO = 0.02
TAMX = (LIMDER-LIMIZQ)/(LIMITE-1)
TAMY = (LIMARRIBA-LIMABAJO)/(LIMITE-1)
pasos(numPasos,z_r,z_i,c_r,c_i) =
if((numPasos < MAXPASOS) && (z_r*z_r+z_i*z_i<4),
pasos(numPasos+1, z_r*z_r - z_i*z_i + c_r, 2*z_r*z_i + c_i, c_r, c_i),
numPasos)
shape fiordos(c_r,c_i) {
#Océano:
FILL[h 214 sat 0.89 b 0.95]
loop i = (LIMITE) [] {
z_i = (LIMARRIBA-LIMABAJO)*i/(LIMITE-1) + LIMABAJO #y
loop j = LIMITE [] {
z_r = (LIMDER-LIMIZQ)*j/(LIMITE-1) + LIMIZQ #x
numPasos = pasos(0, z_r, z_i, c_r, c_i)
if(numPasos<MAXPASOS){
SQUARE[x z_r
y z_i
size TAMX TAMY
h 30 sat 0
b (1+(1-numPasos)/(MAXPASOS-1))]
}
}
}
}
// Función auxiliar
void marcarPixelesCicunferencia(int x, int y, int xc, int yc){
marcarPixel( x+xc, y+yc);
marcarPixel( x+xc,-y+yc);
marcarPixel(-x+xc, y+yc);
marcarPixel(-x+xc,-y+yc);
marcarPixel( y+xc, x+yc);
marcarPixel( y+xc,-x+yc);
marcarPixel(-y+xc, x+yc);
marcarPixel(-y+xc,-x+yc);
}
void circunferencia_punto_medio(int xc, int yc, int radio){
int x,y,d;
x=0;
y=radio;
d=1-radio;
marcarPixelesCicunferencia(x,y, xc,yc);
while(y>x){
if(d<0){
d += x * 2 + 3;
}else{
d += (x - y) * 2 + 5;
y--;
}
x++;
marcarPixelesCicunferencia(x,y, xc,yc);
}
}
# Copyright 2015 Eduardo Adam Navas López
# Este archivo es Software Libre liberado bajo la licencia GNU GPLv3 o su versión más reciente:
# http://www.gnu.org/licenses/gpl.html
#Para generar la imagen:
#$ cfdg -s 8000 -b 0 -x 5 cantor.cfdg cantor.png
startshape principal
shape principal{
loop i=4 []{
SQUARE[s 12 0.9 y (i+1)]
}
cantor[]
CIRCLE[b 1 s 4 z 2 y (-1/2)]
}
shape cantor {
SQUARE[s 12 0.95]
cantor[y -1 x (-12/3) s (1/3) (0.9)]
cantor[y -1 x (12/3) s (1/3) (0.9)]
}
